home *** CD-ROM | disk | FTP | other *** search
/ The CICA Windows Explosion! / The CICA Windows Explosion! - Disc 2.iso / nt / emacssrc.zip / EMACSSRC.TAR / emacs-19.17 / lib-src / rcs2log < prev    next >
Text File  |  1993-11-16  |  10KB  |  382 lines
  1. #!/bin/sh
  2.  
  3. # RCS to ChangeLog generator
  4.  
  5. # Generate a change log prefix from RCS/* and the existing ChangeLog (if any).
  6. # Output the new prefix to standard output.
  7. # You can edit this prefix by hand, and then prepend it to ChangeLog.
  8.  
  9. # Ignore log entries that start with `#'.
  10. # Clump together log entries that start with `{topic} ',
  11. # where `topic' contains neither white space nor `}'.
  12.  
  13. # Author: Paul Eggert <eggert@twinsun.com>
  14.  
  15. # $Id: rcs2log,v 1.12 1993/05/29 06:22:48 rms Exp $
  16.  
  17. # Copyright 1992, 1993 Free Software Foundation, Inc.
  18.  
  19. # This program is free software; you can redistribute it and/or modify
  20. # it under the terms of the GNU General Public License as published by
  21. # the Free Software Foundation; either version 2, or (at your option)
  22. # any later version.
  23. # 
  24. # This program is distributed in the hope that it will be useful,
  25. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  26. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  27. # GNU General Public License for more details.
  28. # 
  29. # You should have received a copy of the GNU General Public License
  30. # along with this program; see the file COPYING.  If not, write to
  31. # the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  32.  
  33. nl='
  34. '
  35.  
  36. # Parse options.
  37.  
  38. # defaults
  39. indent=8 # indent of log line
  40. length=79 # suggested max width of log line
  41. tabwidth=8 # width of horizontal tab
  42.  
  43. while :
  44. do
  45.     case $1 in
  46.     -i)    indent=${2?};;
  47.     -l)    length=${2?};;
  48.     -t)    tabwidth=${2?};;
  49.     -*)    echo >&2 "$0: usage: $0 [-i indent] [-l length] [-t tabwidth] [file ...]"
  50.         exit 1;;
  51.     *)    break
  52.     esac
  53.     shift; shift
  54. done
  55.  
  56. month_data='
  57.     m[0]="Jan"; m[1]="Feb"; m[2]="Mar"
  58.     m[3]="Apr"; m[4]="May"; m[5]="Jun"
  59.     m[6]="Jul"; m[7]="Aug"; m[8]="Sep"
  60.     m[9]="Oct"; m[10]="Nov"; m[11]="Dec"
  61.  
  62.     # days in non-leap year thus far, indexed by month (0-12)
  63.     mo[0]=0; mo[1]=31; mo[2]=59; mo[3]=90
  64.     mo[4]=120; mo[5]=151; mo[6]=181; mo[7]=212
  65.     mo[8]=243; mo[9]=273; mo[10]=304; mo[11]=334
  66.     mo[12]=365
  67. '
  68.  
  69.  
  70. # Log into $rlogout the revisions checked in since the first ChangeLog entry.
  71.  
  72. date=1970
  73. if test -s ChangeLog
  74. then
  75.     # Add 1 to seconds to avoid duplicating most recent log.
  76.     e='
  77.         /^... ... [ 0-9][0-9] [ 0-9][0-9]:[0-9][0-9]:[0-9][0-9] [0-9]+ /{
  78.             '"$month_data"'
  79.             year = $5
  80.             for (i=0; i<=11; i++) if (m[i] == $2) break
  81.             dd = $3
  82.             hh = substr($0,12,2)
  83.             mm = substr($0,15,2)
  84.             ss = substr($0,18,2)
  85.             ss++
  86.             if (ss == 60) {
  87.                 ss = 0
  88.                 mm++
  89.                 if (mm == 60) {
  90.                     mm = 0
  91.                     hh++
  92.                     if (hh == 24) {
  93.                         hh = 0
  94.                         dd++
  95.                         monthdays = mo[i+1] - mo[i]
  96.                         if (i == 1 && year%4 == 0 && (year%100 != 0 || year%400 == 0)) monthdays++
  97.                         if (dd == monthdays + 1) {
  98.                             dd = 1
  99.                             i++
  100.                             if (i == 12) {
  101.                                 i = 0
  102.                                 year++
  103.                             }
  104.                         }
  105.                     }
  106.                 }
  107.             }
  108.             printf "%d/%02d/%02d %02d:%02d:%02d\n", year, i+1, dd, hh, mm, ss
  109.             exit
  110.         }
  111.     '
  112.     d=`awk "$e" <ChangeLog` || exit
  113.     case $d in
  114.     ?*) date=$d
  115.     esac
  116. fi
  117. datearg="-d>$date"
  118.  
  119. # With no arguments, examine all files under the RCS directory.
  120. case $# in
  121. 0)
  122.     files=
  123.     for file in RCS/.* RCS/*
  124.     do
  125.         case $file in
  126.         RCS/. | RCS/..) ;;
  127.         RCS/.\* | RCS/\*) test -f "$file" && files=$files$nl$file;;
  128.         *) files=$files$nl$file
  129.         esac
  130.     done
  131.     case $files in
  132.     '') exit 0
  133.     esac
  134.     oldIFS=$IFS
  135.     IFS=$nl
  136.     set $files
  137.     IFS=$oldIFS
  138. esac
  139.  
  140. rlogout=/tmp/chg$$
  141. trap exit 1 2 13 15
  142. trap 'rm -f $rlogout; exit 1' 0
  143.  
  144. rlog "$datearg" "$@" >$rlogout || exit
  145.  
  146.  
  147. # Get the full name of each author the logs mention, and set initialize_fullname
  148. # to awk code that initializes the `fullname' awk associative array.
  149. # Warning: foreign authors (i.e. not known in the passwd file) are mishandled;
  150. # you have to fix the resulting output by hand.
  151.  
  152. initialize_fullname=
  153. authors=`
  154.     sed -n 's|^date: *[0-9]*/[0-9][0-9]/[0-9][0-9] [0-9][0-9]:[0-9][0-9]:[0-9][0-9]; *author: *\([^; ]*\).*|\1|p' <$rlogout |
  155.     sort -u
  156. `
  157. case $authors in
  158. ?*)
  159.     initialize_author=
  160.     for author in $authors
  161.     do
  162.         initialize_author="$initialize_author
  163.             author[\"$author\"] = 1
  164.         "
  165.     done
  166.  
  167.     awkscript='
  168.         BEGIN {
  169.             alphabet = "abcdefghijklmnopqrstuvwxyz"
  170.             ALPHABET = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  171.             '"$initialize_author"'
  172.         }
  173.         {
  174.             if (author[$1]) {
  175.                 fullname = $5
  176.                 abbr = index(fullname, "&")
  177.                 if (abbr) {
  178.                     a = substr($1, 1, 1)
  179.                     A = a
  180.                     i = index(alphabet, a)
  181.                     if (i) A = substr(ALPHABET, i, 1)
  182.                     fullname = substr(fullname, 1, abbr-1) A substr($1, 2) substr(fullname, abbr+1)
  183.                 }
  184.                 printf "fullname[\"%s\"] = \"%s\"\n", $1, fullname
  185.                 author[$1] = 0
  186.             }
  187.         }
  188.     '
  189.  
  190.     initialize_fullname=`
  191.         (cat /etc/passwd; ypmatch $authors passwd) 2>/dev/null |
  192.         awk -F: "$awkscript"
  193.     `
  194. esac
  195.  
  196.  
  197. # Function to print a single log line.
  198. # We don't use awk functions, to stay compatible with old awk versions.
  199. # `Log' is the log message (with \n replaced by \r).
  200. # `files' contains the affected files.
  201. printlogline='{
  202.  
  203.     # Following the GNU coding standards, rewrite
  204.     #    * file: (function): comment
  205.     # to
  206.     #    * file (function): comment
  207.     if (Log ~ /^\([^)]*\): /) {
  208.         i = index(Log, ")")
  209.         files = files " " substr(Log, 1, i)
  210.         Log = substr(Log, i+3)
  211.     }
  212.  
  213.     # If "label: comment" is too long, break the line after the ":".
  214.     sep = " "
  215.     if ('"$length"' <= '"$indent"' + 1 + length(files) + index(Log, CR)) sep = "\n" indent_string
  216.  
  217.     # Print the label.
  218.     printf "%s*%s:", indent_string, files
  219.  
  220.     # Print each line of the log, transliterating \r to \n.
  221.     while ((i = index(Log, CR)) != 0) {
  222.         printf "%s%s\n", sep, substr(Log, 1, i-1)
  223.         sep = indent_string
  224.         Log = substr(Log, i+1)
  225.     }
  226. }'
  227.  
  228. hostname=`(
  229.     hostname || cat /etc/whoami || uuname -l || uname -n
  230. ) 2>/dev/null` || {
  231.     echo >&2 "$0: cannot deduce hostname"
  232.     exit 1
  233. }
  234.  
  235.  
  236. # Process the rlog output, generating ChangeLog style entries.
  237.  
  238. # First, reformat the rlog output so that each line contains one log entry.
  239. # Transliterate \n to \r so that multiline entries fit on a single line.
  240. # Discard irrelevant rlog output.
  241. awk <$rlogout '
  242.     /^Working file:/ { filename = $3 }
  243.     /^date: /, /^(-----------*|===========*)$/ {
  244.         if ($0 ~ /^branches: /) { next }
  245.         if ($0 ~ /^date: [0-9][ \/0-9:]*;/) {
  246.             time = substr($3, 1, length($3)-1)
  247.             author = substr($5, 1, length($5)-1)
  248.             printf "%s %s %s %s %c", filename, $2, time, author, 13
  249.             next
  250.         }
  251.         if ($0 ~ /^(-----------*|===========*)$/) { print ""; next }
  252.         printf "%s%c", $0, 13
  253.     }
  254. ' |
  255.  
  256. # Now each line is of the form
  257. # FILENAME YYYY/MM/DD HH:MM:SS AUTHOR \rLOG
  258. #    where \r stands for a carriage return,
  259. #    and each line of the log is terminated by \r instead of \n.
  260. # Sort the log entries, first by date+time (in reverse order),
  261. # then by author, then by log entry, and finally by file name (just in case).
  262. sort +1 -3r +3 +0 |
  263.  
  264. # Finally, reformat the sorted log entries.
  265. awk '
  266.     BEGIN {
  267.         # Some awks do not understand "\r" or "\013", so we have to
  268.         # put a carriage return directly in the file.
  269.         CR="" # <-- There is a single CR between the " chars here.
  270.  
  271.         # Initialize the fullname associative array.
  272.         '"$initialize_fullname"'
  273.  
  274.         # Initialize indent string.
  275.         indent_string = ""
  276.         i = '"$indent"'
  277.         if (0 < '"$tabwidth"')
  278.             for (;  '"$tabwidth"' <= i;  i -= '"$tabwidth"')
  279.                 indent_string = indent_string "\t"
  280.         while (1 <= i--)
  281.             indent_string = indent_string " "
  282.  
  283.         # Set up date conversion tables.
  284.         # RCS uses a nice, clean, sortable format,
  285.         # but ChangeLog wants the traditional, ugly ctime format.
  286.  
  287.         # January 1, 0 AD (Gregorian) was Saturday = 6
  288.         EPOCH_WEEKDAY = 6
  289.         # Of course, there was no 0 AD, but the algorithm works anyway.
  290.  
  291.         w[0]="Sun"; w[1]="Mon"; w[2]="Tue"; w[3]="Wed"
  292.         w[4]="Thu"; w[5]="Fri"; w[6]="Sat"
  293.  
  294.         '"$month_data"'
  295.     }
  296.  
  297.     {
  298.         newlog = substr($0, 1 + index($0, CR))
  299.  
  300.         # Ignore log entries prefixed by "#".
  301.         if (newlog ~ /^#/) { next }
  302.  
  303.         if (Log != newlog || date != $2 || author != $4) {
  304.  
  305.             # The previous log and this log differ.
  306.  
  307.             # Print the old log.
  308.             if (date != "") '"$printlogline"'
  309.  
  310.             # Logs that begin with "{clumpname} " should be grouped together,
  311.             # and the clumpname should be removed.
  312.             # Extract the new clumpname from the log header,
  313.             # and use it to decide whether to output a blank line.
  314.             newclumpname = ""
  315.             sep = "\n"
  316.             if (date == "") sep = ""
  317.             if (newlog ~ /^{[^     }]*}[     ]/) {
  318.                 i = index(newlog, "}")
  319.                 newclumpname = substr(newlog, 1, i)
  320.                 while (substr(newlog, i+1) ~ /^[     ]/) i++
  321.                 newlog = substr(newlog, i+1)
  322.                 if (clumpname == newclumpname) sep = ""
  323.             }
  324.             printf sep
  325.             clumpname = newclumpname
  326.  
  327.             # Get ready for the next log.
  328.             Log = newlog
  329.             if (files != "")
  330.                 for (i in filesknown)
  331.                     filesknown[i] = 0
  332.             files = ""
  333.         }
  334.         if (date != $2  ||  author != $4) {
  335.             # The previous date+author and this date+author differ.
  336.             # Print the new one.
  337.             date = $2
  338.             author = $4
  339.  
  340.             # Convert nice RCS date like "1992/01/03 00:03:44"
  341.             # into ugly ctime date like "Fri Jan  3 00:03:44 1992".
  342.             # Calculate day of week from Gregorian calendar.
  343.             i = index($2, "/")
  344.             year = substr($2, 1, i-1) + 0
  345.             monthday = substr($2, i+1)
  346.             i = index(monthday, "/")
  347.             month = substr(monthday, 1, i-1) + 0
  348.             day = substr(monthday, i+1) + 0
  349.             leap = 0
  350.             if (2 < month && year%4 == 0 && (year%100 != 0 || year%400 == 0)) leap = 1
  351.             days_since_Sunday_before_epoch = EPOCH_WEEKDAY + year * 365 + int((year + 3) / 4) - int((year + 99) / 100) + int((year + 399) / 400) + mo[month-1] + leap + day - 1
  352.  
  353.             # Print "date  fullname  (email address)" if the fullname is known;
  354.             # print "date  author" otherwise.
  355.             # Get the fullname from the associative array.
  356.             # The email address is just author@thishostname.
  357.             printf "%s %s %2d %s %d  ", w[days_since_Sunday_before_epoch%7], m[month-1], day, $3, year
  358.             if (fullname[author])
  359.                 printf "%s  (%s@%s)\n\n", fullname[author], author, "'"$hostname"'"
  360.             else
  361.                 printf "%s\n\n", author
  362.         }
  363.         if (! filesknown[$1]) {
  364.             filesknown[$1] = 1
  365.             if (files == "") files = " " $1
  366.             else files = files ", " $1
  367.         }
  368.     }
  369.     END {
  370.         # Print the last log.
  371.         if (date != "") {
  372.             '"$printlogline"'
  373.             printf "\n"
  374.         }
  375.     }
  376. ' &&
  377.  
  378.  
  379. # Exit successfully.
  380.  
  381. exec rm -f $rlogout
  382.